Domino Tips:

This tip was submitted to the SearchDomino.com tip library by member Andrew Broxholme. Please let others know how useful it is via the rating scale at the end of the tip. Do you have a useful Lotus Notes, Domino, Workplace or WebSphere tip or code snippet to share? Submit it to our monthly tip contest and you could win a prize.

In one of our larger applications, there are a number of critical scheduled agents that update data in the application from a back-end relational database. If the connection is lost, or the Lotus Notes database is down, the agents don't run to completion. Agent logs report all activity, but you have to open the logs to check for problems.

Recently the data server failed for an extended period and the logs weren't checked. This led to no updates for 48 hours, until the users noticed and reported the problem to our help desk.

It wasn't a problem to fix the connection and get everything running. But the situation prompted me to write some basic code to e-mail me if the Notes/Domino agents I was most interested in had not run for more than 12 hours.

Monitoring scheduled agents by e-mail involves a procedure that you insert at the end of each agent you want to monitor. This updates a keyword document in the application. You then add another scheduled agent, which runs every 12 hours/every day ,and checks when the agents last ran. If the agents haven't run, then an e-mail is sent to the administrator advising them to check the application and activity logs to see what is going on.

I have included the code for the subroutine which used the existing application keyword form, and a simple agent to check that at least one of the agents have run in the last 12 hours.

 
 Sub logAgentCompletion(agentName As String)
 Dim s As New notesSession
 Dim db As notesDatabase
 Dim view As notesView
 Dim doc As notesDocument
 Dim item As NotesItem
 
 Set db = s.currentdatabase
 Set view = db.getView("vAllKeywords")
 Set doc = view.getDocumentByKey("Last Run of " & agentName, True)
 If Not doc Is Nothing Then
    ' Update the last agent run date and the comments field with the agent name 
  doc.values = Now
  doc.save True, False
  
 Else ' If the document can't be found, create another
  Set doc = db.createDocument
  doc.form = "Keyword"
    ' Have to use ReplaceItemValue because doc.Key is dissallowed (reserved word) 
  Set item = doc.ReplaceItemValue( "Key", "Last Run of " & agentName)
  doc.values = Now
  doc.save True, False
 End If
 
End Sub

The Agent that scans the agent keyword records:

Sub Initialize
 Dim s As New notesSession
 Dim db As notesDatabase
 Dim view As notesView
 Dim collection As notesDocumentCollection
 Dim doc As notesDocument, mailDoc As notesDocument
 Dim checkDate As New notesDateTime(Now)
 Dim lastRunDate As notesDateTime, docDate As notesDateTime
 Dim msgStr As String
 
 Call checkDate.AdjustHour(-12)
 Set db = s.currentDatabase
 Set view = db.getView("vAllKeywords")
 Set collection = view.getAllDocumentsByKey("Last Run of")
 If collection.count > 0 Then
  Set doc = collection.getFirstDocument
  While Not doc Is Nothing
   If Isdate(doc.values(0)) Then
    Set docDate = New notesDateTime(doc.values(0))
    
      ' Find the most recent date that the tracked agents ran 
    If Not lastRunDate Is Nothing Then
     If docDate.lsLocalTime > lastRunDate.lsLocalTime Then
      Set lastRunDate = New notesDateTime(doc.values(0))
     End If
    Else
     Set lastRunDate = New notesDateTime(doc.values(0))
    End If
   End If
   
   Set doc = collection.getNextDocument(doc)
  Wend
  
    ' Send message to system administrator if no activity in last 12 hours 
  If lastRunDate.lsLocalTime < checkDate.lsLocalTime Then
   Set mailDoc = New NotesDocument(db)
   mailDoc.Form = "Memo"
   mailDoc.SendTo = "Andrew Broxholme/Sutton/Security/UK/Corporate"
   mailDoc.Subject = "Alert - OMS Agent's are not running"
   mailDoc.body = "The last time that one of the tracked OMS agents ran was " & lastRunDate.lsLocalTime
   mailDoc.SaveMessageOnSend = False
   Call mailDoc.Send(False)
   
  Else ' Temporary code, can be commented out once we know tracking is working OK
   Set mailDoc = New NotesDocument(db)
   mailDoc.Form = "Memo"
   mailDoc.SendTo = "Andrew Broxholme/Sutton/Security/UK/Corporate"
   mailDoc.Subject = "OMS Agent's running are OK"
   mailDoc.body = "The last run time for the tracked OMS agents ran was " & lastRunDate.lsLocalTime
   mailDoc.SaveMessageOnSend = False
   Call mailDoc.Send(False)
  End If
  
 Else ' If no keyword tracking documents then send alert
  Set mailDoc = New NotesDocument(db)
  mailDoc.Form = "Memo"
  mailDoc.SendTo = "Andrew Broxholme/Sutton/Security/UK/Corporate"
  mailDoc.Subject = "Alert - OMS Agent's are not running"
  mailDoc.body = "No agent activity keywords detected in " & db.title
  mailDoc.SaveMessageOnSend = False
  Call mailDoc.Send(False)
 End If
End Sub